@echo off
::
:: Java konfiguracija - svi postupci
:: PREDUVJET: Direktorij C:\laser postoji i u njemu se nalaze datoteke DeploymentRuleSet.jar, llapp.cer
::
:: 1. Preuzimanje java.security sa Laserline web servera (ne radi na XP-u)
:: 2. Detekcija i postavljanje JAVA_HOME varijable
:: 3. Provjera postoji li C:\laser i u njemu DeploymentRuleSet.jar i llapp.cer - ako ih nema IZLAZ
:: 4. Provjera postoji li direktorij C:\Windows\Sun\Java\Deployment\, ako ga nema, kreiranje
:: 5. Zamjena java.security datoteke ako je preuzeta
:: 6. Kopiranje DeploymentRuleSet.jar i llapp.cer u C:\Windows\Sun\Java\Deployment\
:: 7. Importiranje certifikata u %JAVA_HOME%\lib\security\cacerts
:: 8. Everyone Full Control na JAVA HOME direktorij (ne radi na XP-u)
::
:: Ivica Glavocic, Laserline, 2018-02
::
:: RUN AS ADMINISTRATOR
::
:: Inicijalne postavke
::
if not exist "C:\laser" mkdir "C:\laser"
set JAVA_HOME=nepoznato
set FILE_SEC=C:\laser\java.security.8u131plus
set FILE_DRS=C:\laser\DeploymentRuleSet.jar
set FILE_CER=C:\laser\llapp.cer
setlocal EnableExtensions EnableDelayedExpansion
::
:: Preuzimanje java.security sa Laserline web servera
::
bitsadmin.exe /transfer "Java Security" /priority FOREGROUND http://laser6.laserline.hr/download/java.security.8u131plus "%FILE_SEC%"
::
:: Detekcija i postavljanje JAVA_HOME varijable
::
echo.
IF %PROCESSOR_ARCHITECTURE%==x86 (
    set OS_BIT=32
    FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment" /v CurrentVersion') DO set CurVer=%%B
    FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment\!CurVer!" /v JavaHome') DO set JAVA_HOME=%%B
 ) ELSE ( 
    set OS_BIT=64
    FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\WOW6432Node\JavaSoft\Java Runtime Environment" /v CurrentVersion') DO set CurVer=%%B
    FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\WOW6432Node\JavaSoft\Java Runtime Environment\!CurVer!" /v JavaHome') DO set JAVA_HOME=%%B
)
echo --- JAVA detektirana u direktoriju %JAVA_HOME%
::
:: Provjera postoji li C:\laser i u njemu DeploymentRuleSet.jar i llapp.cer - ako ih nema IZLAZ
::
echo.
if exist "%FILE_DRS%" (
	echo --- Datoteka DeploymentRuleset.jar postoji u direktoriju C:\laser
 ) ELSE ( 
	echo --- Datoteka DeploymentRuleset.jar NE POSTOJI u direktoriju C:\laser
	echo --- Pritisnite bilo koju tipku za izlaz
	PAUSE > nul
	exit
)
if exist "%FILE_CER%" (
	echo --- Datoteka llapp.cer postoji u direktoriju C:\laser
 ) ELSE ( 
	echo --- Datoteka llapp.cer NE POSTOJI u direktoriju C:\laser
	echo --- Pritisnite bilo koju tipku za izlaz
	PAUSE > nul
	exit
)
::
:: Provjera postoji li direktorij C:\Windows\Sun\Java\Deployment\, ako ga nema, kreiranje
::
if not exist C:\Windows\Sun\Java\Deployment\ mkdir C:\Windows\Sun\Java\Deployment\
::
:: Zamjena java.security datoteke ako je preuzeta
::
echo.
if exist "%FILE_SEC%" (
	echo --- Backup java.security u java.security.old
	copy /Y "%JAVA_HOME%\lib\security\java.security" "%JAVA_HOME%\lib\security\java.security.old"
	echo --- Zamjena java.security
	xcopy /E /C /F /Y "%FILE_SEC%" "%JAVA_HOME%\lib\security\java.security"
 ) ELSE ( 
	echo --- Datoteka java.security.8u131plus NIJE preuzeta u direktorij C:\laser
	echo --- Java.Security NECE biti modificirana
)
::
:: Kopiranje DeploymentRuleSet.jar i llapp.cer u C:\Windows\Sun\Java\Deployment\
::
echo.
echo --- Kopiram DeploymentRuleset.jar
xcopy /E /C /F /Y "C:\laser\DeploymentRuleSet.jar" "C:\Windows\Sun\Java\Deployment\"
echo.
echo --- Kopiram certifikat llapp.cer
xcopy /E /C /F /Y "C:\laser\llapp.cer" "C:\Windows\Sun\Java\Deployment\"
::
:: Importiranje certifikata u %JAVA_HOME%\lib\security\cacerts
::
echo.
echo --- Importiram certifikat
cd C:\Windows\Sun\Java\Deployment\
"%JAVA_HOME%\bin\keytool.exe" -import -alias llapp -file "llapp.cer" -keystore "%JAVA_HOME%\lib\security\cacerts"  -storepass changeit -noprompt
::
:: Everyone Full Control na JAVA HOME direktorij
::
echo.
echo --- "%JAVA_HOME%" - Everyone Full Control
icacls "%JAVA_HOME%" /grant Everyone:(OI)(CI)F /T /C /Q
echo.
echo --- Java Config skripta je odradila promjene na vasem racunalu
echo.
echo ***** PRITISNITE BILO KOJU TIPKU ZA KRAJ *****
PAUSE > nul
exit